* В следующем примере команда DEFINE POPUP используется для
* создания меню, активизируемых при выборе заголовка меню в строке
* меню. Сначала текущая системная строка меню сохраняется в памяти с
* помощью команды SET SYSMENU SAVE, а затем все заголовки системных
* меню удаляются по команде SET SYSMENU TO.

* С помощью команды DEFINE PAD создаются два новых заголовка
* системных меню, а команда DEFINE POPUP создает раскрывающиеся
* меню для каждого из заголовков. Команда DEFINE BAR создает
* элементы в каждом из меню. Когда выбирается заголовок меню,
* команда ON PAD с помощью ACTIVATE POPUP активизирует
* соответствующее меню.

* Когда в меню выбирается элемент, команда ON SELECTION POPUP с
* помощью функций PROMPT( ) и POPUP( ) передает номер элемента и имя
* меню процедуре CHOICE. Эта процедура отображает текст выбранного
* элемента и имя содержащего его меню. Если выбрать элемент Exit в
* меню Card Info, восстанавливается первоначальная система меню Visual
* FoxPro.

*** Name this program DEFINPOP.PRG ***

CLEAR

SET SYSMENU SAVE

SET SYSMENU TO

DEFINE PAD convpad OF _MSYSMENU PROMPT '\<Conversions' COLOR SCHEME 3 ;

KEY ALT+C, ''

DEFINE PAD cardpad OF _MSYSMENU PROMPT 'Card \<Info' COLOR SCHEME 3 ;

KEY ALT+I, ''

ON PAD convpad OF _MSYSMENU ACTIVATE POPUP conversion

ON PAD cardpad OF _MSYSMENU ACTIVATE POPUP cardinfo

DEFINE POPUP conversion MARGIN RELATIVE SHADOW COLOR SCHEME 4

DEFINE BAR 1 OF conversion PROMPT 'Ar\<ea' KEY CTRL+E, '^E'

DEFINE BAR 2 OF conversion PROMPT '\<Length' ;

KEY CTRL+L, '^L'

DEFINE BAR 3 OF conversion PROMPT 'Ma\<ss' ;

KEY CTRL+S, '^S'

DEFINE BAR 4 OF conversion PROMPT 'Spee\<d' ;

KEY CTRL+D, '^D'

DEFINE BAR 5 OF conversion PROMPT '\<Temperature' ;
KEY CTRL+T, '^T'

DEFINE BAR 6 OF conversion PROMPT 'T\<ime' ;
KEY CTRL+I, '^I'

DEFINE BAR 7 OF conversion PROMPT 'Volu\<me' ;

KEY CTRL+M, '^M'

ON SELECTION POPUP conversion;

DO choice IN definpop WITH PROMPT( ), POPUP( )

DEFINE POPUP cardinfo MARGIN RELATIVE SHADOW COLOR SCHEME 4

DEFINE BAR 1 OF cardinfo PROMPT '\<View Charges' ;

KEY ALT+V, ''

DEFINE BAR 2 OF cardinfo PROMPT 'View \<Payments' ;

KEY ALT+P, ''

DEFINE BAR 3 OF cardinfo PROMPT 'Vie\<w Users' ;

KEY ALT+W, ''

DEFINE BAR 4 OF cardinfo PROMPT '\-'

DEFINE BAR 5 OF cardinfo PROMPT '\<Charges '

DEFINE BAR 6 OF cardinfo PROMPT '\-'

DEFINE BAR 7 OF cardinfo PROMPT 'E\<xit '

ON SELECTION POPUP cardinfo;
DO choice IN definpop WITH PROMPT( ), POPUP( )

PROCEDURE choice

PARAMETERS mprompt, mpopup

WAIT WINDOW 'You chose ' + mprompt + ;
' from popup ' + mpopup NOWAIT

IF mprompt = 'Exit'

SET SYSMENU TO DEFAULT

ENDIF